shared_library("liteipc_simulator") {
    sources = [
        "simulator/liteipc_simulator.c",
        "simulator/liteipc_simulator.h",
        "simulator/liteipc_simulator_pri.h",
    ]

    include_dirs = [
        "simulator",
        "//foundation/communication/ipc_lite/frameworks/liteipc/include",
        "//foundation/communication/ipc_lite/interfaces/kits",
    ]

    cflags = [
        "-Wall"
    ]
}

executable("liteipc_simulator_init") {
    sources = [
        "simulator/init.c",
        "simulator/liteipc_simulator_pri.h",
    ]
    include_dirs = [
        "simulator",
        "//foundation/communication/ipc_lite/frameworks/liteipc/include",
        "//foundation/communication/ipc_lite/interfaces/kits",
    ]
    ldflags = [ "-lrt", "-pthread" ]
    deps = [ ":liteipc_simulator" ]
    output_dir = "$root_out_dir"
}

shared_library("liteipc_adapter") {
    sources = [
        "adapter/liteipc_adapter.c",
        "//foundation/communication/ipc_lite/frameworks/liteipc/src/serializer.c",
        "simulator/liteipc_simulator.h",
    ]
    cflags = ["-fPIC"]
    cflags += ["-Wall"]
    ldflags = ["-lrt"]
    cflags_cc = cflags
    public_configs = [":liteipc_external_library_config"]
    include_dirs = [
        "simulator",
        "//foundation/communication/ipc_lite/frameworks/liteipc/include",
        "//third_party/bounds_checking_function/include",
    ]
    public_deps = [ "//third_party/bounds_checking_function/:libsec_shared" ]
    deps = [
        ":liteipc_simulator",
        "//base/hiviewdfx/hilog_lite/frameworks/featured:hilog_shared",
    ]
}

config("liteipc_external_library_config") {
    include_dirs = [
        "//foundation/communication/ipc_lite/interfaces/kits",
        "//utils/native/lite/include",
    ]
}

group("liteipc") {
    public_deps = [
        ":liteipc_adapter",
    ]
    deps = [
        ":liteipc_simulator_init",
    ]
}

executable("liteipc_simulator_remove") {
    sources = [
        "utils/remove.c",
        "simulator/liteipc_simulator_pri.h",
    ]
    include_dirs = [
        "simulator",
        "//foundation/communication/ipc_lite/frameworks/liteipc/include",
        "//foundation/communication/ipc_lite/interfaces/kits",
    ]
    ldflags = [ "-lrt", "-pthread" ]
    output_dir = "$root_out_dir"
}

template("simulator_test") {
    forward_variables_from(invoker, "*")

    executable(invoker.target_name) {
        sources = [
            "test/" + invoker.target_name + ".c",
            "simulator/liteipc_simulator.h",
        ]

        include_dirs = [
            "simulator",
            "//foundation/communication/ipc_lite/frameworks/liteipc/include",
            "//foundation/communication/ipc_lite/interfaces/kits",
        ]

        ldflags = [ "-lrt", "-pthread" ]

        deps = [
            ":liteipc_simulator"
        ]

        output_dir = "$root_out_dir"
    }
}

simulator_test("liteipc_simulator_test1") { }
simulator_test("liteipc_simulator_test2") { }
simulator_test("liteipc_simulator_test2a") { }
simulator_test("liteipc_simulator_test3") { }
simulator_test("liteipc_simulator_test4") { }
simulator_test("liteipc_simulator_test5_server") { }
simulator_test("liteipc_simulator_test5_client") { }

group("samples") {
    deps = [ "sample/ohdsbench" ]
}