import org.apache.tools.ant.filters.ReplaceTokens
import org.jetbrains.kotlin.gradle.dsl.JvmTarget

ext {
    println("Environment                 : JAVA_HOME=$System.env.JAVA_HOME")
    println("Gradle Version              : ${projectProperties.getProperty('gradleVersion')}")
    println("Target JDK Version          : ${projectProperties.getProperty('javaVersion')}")
    println("Kotlin Version              : $versions.kotlin")
    println("Solon  Version              : $versions.solon")
    println("Spring Boot Version         : $versions.springBoot")
    println("Spring Cloud Version        : $versions.springCloud")
    println("Spring Cloud Alibaba Version: $versions.springCloudAlibaba")
    println("Encoding                    : ${projectProperties.getProperty('encoding')}")
    println("Build Version               : ${projectProperties.getProperty('version')}")
}

buildscript {
    ext {
        projectProperties = new Properties()
        projectProperties.load(new FileInputStream("$rootDir${File.separator}project.properties"))
    }
    apply from: "$rootDir${File.separator}gradle${File.separator}dependencies.gradle"
    dependencies {
        classpath "org.jetbrains.kotlin:kotlin-gradle-plugin:$versions.kotlin"
        classpath "org.jetbrains.kotlin:kotlin-allopen:$versions.kotlin"
        classpath "org.jetbrains.kotlin:kotlin-noarg:$versions.kotlin"
        classpath "tech.yanand.maven-central-publish:tech.yanand.maven-central-publish.gradle.plugin:$versions.mavenCentralPublish"
        classpath "org.springframework.boot:spring-boot-gradle-plugin:$versions.springBoot"
        classpath "org.graalvm.buildtools.native:org.graalvm.buildtools.native.gradle.plugin:$versions.nativePlugin"
    }
    repositories {
        mavenLocal()
        maven {
            url = new URI(projectProperties.getProperty('mavenSnapshotsUrl').toString())
        }
        maven {
            url = new URI(projectProperties.getProperty('mavenCentralUrl').toString())
        }
        mavenCentral()
    }
}

apply from: "$rootDir${File.separator}gradle${File.separator}globalTask.gradle"

allprojects {

    group = project.group.toString().isBlank() ? projectProperties.getProperty('group') : "${projectProperties.getProperty('group')}.$project.group"
    version = projectProperties.getProperty('version')

    apply from: "$rootDir${File.separator}gradle${File.separator}dependencies.gradle"

    apply plugin: 'java'
    apply plugin: 'kotlin'
    apply plugin: 'kotlin-spring'
    apply plugin: 'kotlin-noarg'
    apply plugin: 'idea'

    apply from: "$rootDir${File.separator}gradle${File.separator}environment.gradle"
    apply from: "$rootDir${File.separator}gradle${File.separator}commonTask.gradle"

    buildscript {
        repositories {
            mavenLocal()
            maven {
                url = new URI(projectProperties.getProperty('mavenSnapshotsUrl').toString())
            }
            maven {
                url = new URI(projectProperties.getProperty('mavenCentralUrl').toString())
            }
            mavenCentral()
        }
    }

    repositories {
        mavenLocal()
        maven {
            url = new URI(projectProperties.getProperty('mavenSnapshotsUrl').toString())
        }
        maven {
            url = new URI(projectProperties.getProperty('mavenCentralUrl').toString())
        }
        mavenCentral()
    }

    dependencies {
        testImplementation platform("org.junit:junit-bom:$versions.junit")
        testImplementation("org.junit.jupiter:junit-jupiter")
        testImplementation("org.junit.platform:junit-platform-launcher")
    }

    java {
        sourceCompatibility = projectProperties.getProperty('javaVersion')
        targetCompatibility = projectProperties.getProperty('javaVersion')
        withJavadocJar()
        withSourcesJar()
    }

    javadoc {
        options.encoding = projectProperties.getProperty('encoding')
        options.addStringOption('Xdoclint:none', '-quiet')
    }

    kotlin {
        compilerOptions {
            allWarningsAsErrors = true
            javaParameters = true
            jvmTarget = JvmTarget.valueOf("JVM_" + projectProperties.getProperty('javaVersion'))
        }
    }

    processResources {
        def tokens = [:]
        project.properties.each { key, value ->
            if (value != null) {
                tokens[key] = value.toString()
            }
        }
        duplicatesStrategy = DuplicatesStrategy.INCLUDE
        from(sourceSets.main.resources.srcDirs) {
            filter(ReplaceTokens, tokens: tokens)
        }
    }

    compileJava {
        dependsOn(processResources)
        options.encoding = projectProperties.getProperty('encoding')
        options.compilerArgs << "-parameters"
    }
    compileTestJava {
        dependsOn(processResources)
        options.encoding = projectProperties.getProperty('encoding')
        options.compilerArgs << "-parameters"
    }
    compileKotlin {
        dependsOn(processResources)
    }
    compileTestKotlin {
        dependsOn(processResources)
    }

    test {
        useJUnitPlatform()
        testLogging {
            events "standardOut", "started", "passed", "skipped", "failed"
        }
        exclude "**${File.separator}*nobuild**"
    }
}