apply plugin: 'maven-publish'
apply plugin: 'signing'
apply plugin: 'org.jreleaser'
publishing {
    publications {
        maven(MavenPublication) {
            //打包类型 war: components.web jar: components.java
            from components.java
            //指定group/artifact/version信息
            groupId = project.group
            artifactId = project.name
            version = project.version
            pom {
                packaging = "jar"
                name = "acp"
                description = "Application Construction Platform 应用构建平台"
                url = "https://gitee.com/zhangbinhub/acp"
                licenses {
                    license {
                        name = "Apache License Version 2.0"
                        url = "http://www.apache.org/licenses/LICENSE-2.0"
                    }
                }
                developers {
                    developer {
                        id = "zhangbinhub"
                        name = "zhangbin"
                        email = "zhangbin1010@qq.com"
                    }
                }
                scm {
                    connection = "scm:git:https://gitee.com/zhangbinhub/acp.git"
                    developerConnection = "scm:git:https://gitee.com/zhangbinhub/acp.git"
                    url = "https://gitee.com/zhangbinhub/acp"
                }
            }
        }
    }
    repositories {
        maven {
            url = layout.buildDirectory.dir('staging-deploy')
        }
    }
}
signing {
    required = {
        def file = new File("$rootDir${File.separator}gradle.properties")
        if (file.exists()) {
            def gradleProperties = new Properties()
            gradleProperties.load(new FileInputStream(file))
            if (!gradleProperties.getProperty('signing.keyId', '').isBlank()) {
                return true
            }
        }
        return false
    }
    sign publishing.publications.maven
}
jreleaserDeploy {
    dependsOn(publish)
}
jreleaser {
    deploy {
        maven {
            mavenCentral {
                def file = new File("$rootDir${File.separator}gradle.properties")
                def deployUrl = 'https://central.sonatype.com/api/v1/publisher'
                def name = ''
                def pwd = ''
                if (file.exists()) {
                    def gradleProperties = new Properties()
                    gradleProperties.load(new FileInputStream(file))
                    deployUrl = gradleProperties.containsKey('mavenCentralUrl') ? "${mavenCentralUrl}" : deployUrl
                    name = gradleProperties.containsKey('mavenUserName') ? "${mavenUserName}" : name
                    pwd = gradleProperties.containsKey('mavenUserName') ? "${mavenPassword}" : pwd
                }
                sonatype {
                    sign = false
                    verifyPom = false
                    active = 'ALWAYS'
                    url = deployUrl
                    username = name
                    password = pwd
                    authorization = 'Basic'
                    stagingRepository('build/staging-deploy')
                    connectTimeout = 20
                    readTimeout = 600
                    retryDelay = 10
                    maxRetries = 100
                }
            }
        }
    }
}