configure(allprojects) { project ->
	group = PROJ_GROUP
	version = PROJ_VERSION

	apply plugin: "java"
	apply plugin: "maven-publish"
	apply plugin: "eclipse"
	apply plugin: "idea"
	apply plugin: "signing"
	apply plugin: "maven"
	eclipse {
		jdt {
			//if you want to alter the java versions (by default they are configured with gradle java plugin settings):
			sourceCompatibility = SOURCE_COMPILER_LEVEL
			targetCompatibility = TARGET_COMPILER_LEVEL
			//javaRuntimeName = "../../org.eclipse.jdt.launching.JRE_CONTAINER"

		}
	}

	tasks.withType(JavaCompile) {

		sourceCompatibility = SOURCE_COMPILER_LEVEL
		targetCompatibility = TARGET_COMPILER_LEVEL
		options.encoding = 'UTF-8'
	}

	tasks.withType(Javadoc) {
		sourceCompatibility = JAVADOC_SOURCE_LEVEL
		targetCompatibility = JAVADOC_COMPILER_LEVEL
		options.encoding = 'UTF-8'
		// disable the crazy super-strict doclint tool in Java 8
        // noinspection SpellCheckingInspection
		if (JavaVersion.current().isJava8Compatible()) {
			options.addStringOption('Xdoclint:none', '-quiet')
		}
	}

	task sourcesJar(type: Jar) {
		classifier = "sources"
		from sourceSets.main.allJava
	}

	task javaDocJar(type: Jar, dependsOn: javadoc) {
		classifier = "javadoc"
		from javadoc.destinationDir
	}
	artifacts {
		archives sourcesJar, javaDocJar
	}

	jar {
		manifest {
			attributes (
					'Implementation': version,
					'Specification-Version': version,
					'Implementation-Vendor': 'bbossgroups',
					'Implementation-ProductID': project.name,
					'Compile-Timestamp': new Date().format('yyyy-MM-dd HH:mm:ss'),
					'Compile-User': DEVELOPER_NAME
			)
		}
	}




	repositories {
		mavenLocal()
		 maven {
	        url "http://maven.aliyun.com/nexus/content/groups/public"
	    }
		 maven {
	        url "https://artifacts.elastic.co/maven"
	    } 
		mavenCentral()

	}
	if(project.getProperty('skipTest').equals("true"))
	{
		compileTestJava.enabled=false
		processTestResources.enabled=false
		testClasses.enabled = false
		test.enabled = false
	}

	sourceSets {
		main {
			java {
				srcDir 'src/main/java'

			}
			resources {
				srcDir 'src/main/resources'
				srcDir 'src/main/java'  exclude '**/*.java'
			}
			compileClasspath = configurations.compile + configurations.runtime
		}
		test {
			java {
				srcDir 'src/test/java'

			}
			resources {
				srcDir 'src/test/resources'
				srcDir 'src/test/java'  exclude '**/*.java'
			}

		}

	}



	dependencies {
		testCompile 'junit:junit:4.12'
	
		compile(
				fileTree(dir: 'lib', include: '**/*'),
				//[group: 'com.navercorp.pinpoint', name: 'pinpoint-annotations', version: "${pinpoint_version}", transitive: false],
				//[group: 'com.navercorp.pinpoint', name: 'pinpoint-bootstrap-core', version: "${pinpoint_version}", transitive: false],
				//[group: 'com.navercorp.pinpoint', name: 'pinpoint-commons', version: "${pinpoint_version}", transitive: false],

				[group: 'com.bbossgroups', name: 'bboss-core', version: "${bboss_version}", transitive: true],
				[group: 'com.bbossgroups', name: 'bboss-velocity', version: "${bboss_version}", transitive: true],
		)
		runtime(
				[group: 'com.bbossgroups', name: 'bboss-rt', version: "${bboss_version}", transitive: false],
		)
	}



	task copyJarFiles(type: Sync,dependsOn:'jar'){
		from fileTree(dir: 'lib', include: '**/*')
		from configurations.compile
		from jar.outputs
		into 'build/dist/lib'

	}

	task copyRTJarFiles(type: Copy,dependsOn:['copyJarFiles']){
		
//		 from configurations.runtime
		from configurations.runtime-configurations.compile
		into 'build/dist'
	     rename ("bboss-rt-${bboss_version}.jar", "${project.name}-bootstrap-${bboss_version}.jar")
	}
	task copyToolFiles(type: Copy ,dependsOn:'copyRTJarFiles')  {
		
		from ('runfiles')
			{
				expand(
						bboss_version:"${bboss_version}",
                                                project:"${project.name}",
                                                RT_JAVA_OPTS:"-server"
						)

			}		
		filteringCharset = 'UTF-8'
		into 'build/dist/'



	}
	task copyResourcesfiles(type: Sync )  {
		from fileTree(dir: 'src/test/resources')
		filteringCharset = 'UTF-8'
		into 'build/dist/resources'
	}

	task releaseVersion(type: Zip,dependsOn:['copyToolFiles','copyResourcesfiles']) {

		//appendix = 'wrapper'
		classifier = 'released'
		from 'build/dist/'

	}

}