apply from: './dependencies.gradle'
apply from: rootDir.canonicalPath + '/.gradle/publish.gradle'

allprojects {
  apply plugin: 'java'
  apply plugin: 'maven'
  apply plugin: 'signing'
  apply plugin: 'idea'
  apply plugin: 'eclipse'

  sourceCompatibility = 1.8
  targetCompatibility = 1.8

  configurations {
    provided
    all*.exclude module: 'spring-boot-starter-logging'
  }
  
  dependencies {
    compileOnly libs.'lombok' 
    annotationProcessor libs.'lombok'
    testCompileOnly libs.'lombok'
    testAnnotationProcessor libs.'lombok'
  }
}

project(':mx-utils') {
	group = 'io.gitee.johnpeng'
    version = '5.0.9'
    description = 'Many utility java class, such as : DateUtils, StringUtils, etc.'
    
    dependencies {
        compile(
                libs.'fastjson',
                libs.'log4j-api',
                libs.'log4j-core',
                libs.'log4j-slf4j-impl',
                libs.'slf4j-api',
                libs.'commons-lang3'
        )
    }
}

project(':mx-spring') {
	group = 'io.gitee.johnpeng'
    version = '5.1.9'
    description = 'Many utility based on spring, such as : SpringContextHolder, etc.'

    dependencies {
        compile(
                project(':mx-utils'),
                libs.'log4j-core',
                libs.snakeyaml,
                libs.'spring-context-support',
                libs.ehcache,
                libs.'spring-data-redis',
                libs.'spring-boot-starter',
                libs.'commons-pool2',
        		libs.'commons-beanutils',
        		libs.validation,
                libs.jedis
        )
        testCompile(
                libs.'spring-boot-starter-test'
        )
    }
}

project(':mx-jwt-utils') {
	group = 'io.gitee.johnpeng'
    version = '5.1.3'
    description = 'Many json web tokens utility.'

    dependencies {
        compile(
                project(':mx-spring'),
                libs.'java-jwt',
                libs.'javassist'
        )
    }
}

project(':mx-dal') {
	group = 'io.gitee.johnpeng'
    version = '5.0.4'
    description = 'data access layer abstract classes and interfaces.'

    dependencies {
        compile(
                project(':mx-utils'),
                project(':mx-spring')
        )
    }
}

project(':mx-service-utils') {
	group = 'io.gitee.johnpeng'
    version = '5.3.10'
    description = 'Many service utilities class, with Jetty, include: RESTful, Servlet, Websocket.'

    dependencies {
        compile(
                project(':mx-utils'),
                project(':mx-spring'),
                project(':mx-jwt-utils'),
                project(':mx-dal'),
                libs.'fastjson',
                libs.'log4j-core',
                libs.'jaxb-api',
                libs.'jaxb-core',
                libs.'jaxb-impl',
                libs.'netty',
                libs.'activation',
                libs.'jersey-server',
                libs.'jersey-media-jackson',
                libs.'jersey-media-multi',
                libs.'jersey-jetty-http',
                libs.'jersey-jetty-servlet',
                libs.'jersey-hk2',
                libs.'jetty-server',
                libs.'jetty-servlet',
                libs.'jetty-websocket',
                libs.'graphql',
                libs.'httpclient',
                libs.'snakeyaml',
                libs.'spring-web',
                libs.'rocketmq'
        )
        compile(libs.'jersey-spring5') {
            exclude module: 'spring-web'
        }
    }
}

project(':mx-dal-rdb') {
	group = 'io.gitee.johnpeng'
    version = '5.1.2'
    description = 'Dal with RDB, dal hibernate or mybatis-plus will be based it.'

    dependencies {
        compile(
                project(':mx-dal'),
                project(':mx-service-utils'),
                libs.'spring-jdbc',
                libs.'spring-tx',
                libs.h2database,
                libs.'commons-dbcp2',
                libs.'google-annotations'
        )
    }
}

project(':mx-dal-hibernate') {
	group = 'io.gitee.johnpeng'
    version = '5.2.4'
    description = 'Dal with hibernate JPA.'

    dependencies {
        compile(
        		project(':mx-spring'),
                project(':mx-dal-rdb'),
                libs.'spring-orm',
                libs.'spring-oxm',
                libs.'spring-data-jpa',
                libs.dom4j,
                libs.'javax-el-api',
                libs.'javax-el',
                libs.'atomikos-jta',
                libs.'atomikos-hibernate4',
                libs.'hibernate-entitymanager',
                libs.'hibernate-validator'
        )
        testCompile(
                libs.postgresql,
                libs.mysql8
        )
    }
}

project(':mx-dal-mybatisplus') {
	group = 'io.gitee.johnpeng'
	version = '5.1.0'
	description = 'Dal with mybatis & mybatis-plus.'
	
	dependencies {
		compile(
			project(':mx-dal-rdb'),
			libs.'mybatis-plus-boot-starter'
		)
		testCompile(
			libs.postgresql,
			libs.mysql8
		)
	}
}

project(':mx-dal-mongodb') {
	group = 'io.gitee.johnpeng'
    version = '5.1.4'
    description = 'dal with mongoldb.'

    dependencies {
        compile(
                project(':mx-dal'),
                libs.'spring-beans',
                //libs.'log4j-core',
                libs.snakeyaml,
                libs.'mongodb-driver'
        )
        compile(libs.'spring-data-mongodb') {
        	exclude module: 'mongodb-driver-core'
        }
        testCompile(
                libs.'mongodb-embed',
                libs.'spring-boot-starter-test'
        )
    }
}

project(':mx-dal-elastic') {
	group = 'io.gitee.johnpeng'
    version = '5.2.1'
    description = 'dal with elasticsearch.'
    
    dependencies {
        compile(
                project(':mx-dal'),
                libs.'elasticsearch-java',
                libs.'jackson-databind',
                libs.'json-api'
        )
        compile(project(':mx-service-utils')) {
            exclude module: 'jboss-logging'
            exclude module: 'classmate'
        }
    }
}

project(':mx-notify-service-utils') {
	group = 'io.gitee.johnpeng'
	version ='1.0.2'
	description = 'Message notify server framework based on WebSocket.'
	
	dependencies {
		compile(
			project(':mx-service-utils'),
			libs.'dom4j'
		)
		testCompile(
	    	libs.'spring-test',
	    	libs.'httpclient'
	    )
	}
}

subprojects { subprj ->
  repositories {
    mavenCentral()
    mavenLocal()
  }
  dependencies {
    compile fileTree(dir: 'libs', include: ['*.jar'])
    testCompile(
      libs.'junit'
    )
  }
  jar {
    manifest.attributes provider: 'MX Foundation.'
    excludes = []
  }
  task sourcesJar(type: Jar) {
    classifier = 'sources'
    from sourceSets.main.allSource
  }
  task javadocJar(type: Jar) {
    classifier = 'javadoc'
    from javadoc
  }
  artifacts {
  	archives javadocJar, sourcesJar
  }
  signing {
  	// sign publishing.publications.mavenJava
  	sign configurations.archives
  }
  uploadArchives {
  	repositories {
  		mavenDeployer {
  			beforeDeployment {
  				MavenDeployment deployment -> signing.signPom(deployment)
  			}
  			
  			repository(url: "https://s01.oss.sonatype.org/service/local/staging/deploy/maven2/") {
        		authentication(userName: project.sonatypeUsername, password: project.sonatypePassword)
      		}
  			snapshotRepository(url: "https://s01.oss.sonatype.org/content/repositories/snapshots/") {
        		authentication(userName: project.sonatypeUsername, password: project.sonatypePassword)
      		}
      		pom.project {
      			// 构件名称，区别于artifactId，可理解为artifactName
  				name = 'org.mx base'
  				packaging 'jar'
  				description = 'org.mx base java library.'
  				url = 'https://gitee.com/johnpeng/mx-core'
  				licenses {
  					license {
  						name = 'The Apache License, Version 2.0'
  						url = 'http://www.apache.org/licenses/LICENSE-2.0.txt'
  					}
  					license {
  						name = 'MIT'
  						url = 'http://doge.mit-license.org'
  					}
  				}
  				developers {
  					developer {
  						name = '彭明喜'
  						email = 'josh_73_9@hotmail.com'
  					}
  				}
  				scm {
  					url = 'https://gitee.com/johnpeng/mx-core.git'
  					connection = 'scm:git:git://gitee.com/johnpeng/mx-core.git'
  					developerConnection = 'scm:git:ssh://gitee.com/johnpeng/mx-core.git'
  				}
      		}
  		}
  	}
  }
  task copyDependencies(type: Copy) {
    into "$buildDir/dependencies"
    from configurations.runtime
  }
  [compileJava, compileTestJava, javadoc]*.options*.encoding = 'UTF-8'
  javadoc {
  	// 防止本地打开中文乱码
  	options.addStringOption("charset", "UTF-8")
  }
}