allprojects {
    ext{
        gradleScriptHome = "https://gitee.com/ltalex/gradle-script/raw/master/"
    }
    apply from: gradleScriptHome + 'maven.gradle'
    /**
     * dependencies-version.gradle是项目依赖所需的类库/框架的版本定义。
     * 类库相关版本请参照: https://gitee.com/ltalex/gradle-script/raw/master/library-version.gradle
     * 框架相关版本请参照: https://gitee.com/ltalex/gradle-script/raw/master/framework-version.gradle
     */
    apply from: gradleScriptHome + 'dependencies-version.gradle'

    group 'com.pureland'
    version '1.0.RELEASE'

    apply plugin : 'java'
    apply plugin : 'idea'

    sourceCompatibility = 1.8

    /**
     * 设置编译时期的编码方式
     */
    tasks.withType(JavaCompile) {
        options.encoding = "UTF-8"
    }

    java {
        withJavadocJar()
        withSourcesJar()
    }

    /**
     * JavaDoc文档设置
     */
    javadoc {
        options.addStringOption('Xdoclint:none', '-quiet')
        options.addStringOption('encoding', 'UTF-8')
        options.addStringOption('charSet', 'UTF-8')
        if(JavaVersion.current().isJava9Compatible()) {
            options.addBooleanOption('html5', true)
        }
    }


    /**
     * maven-publish插件,与Tasks->upload->uploadArchives功能类似
     * 这里以maven-publish插件的方式发布到远程/本地仓库
     * 如果只是发布到本地maven仓库,Tasks->other->install
     */
    publishing {
        repositories {
            maven {
                def snapshotsRepoUrl = COMPANY_NEXUS_REPOSITORY_HOME + "/repository/maven-snapshots/"
                def releasesRepoUrl = COMPANY_NEXUS_REPOSITORY_HOME + "/repository/maven-releases/"
                credentials {
                    username 'admin'
                    password 'admin'
                }
                url  project.version.endsWith('RELEASE') ?  releasesRepoUrl : snapshotsRepoUrl
            }
        }

        publications {
            mavenJava(MavenPublication) {
                groupId project.group
                artifactId  project.name
                version project.version
                from components.java
            }
        }
    }
}