buildscript {
  repositories {
    mavenLocal()
    mavenCentral()
    maven {
      url "https://repo.spring.io/plugins-release"
    }
    jcenter()
  }

  dependencies {
    classpath "nl.javadude.gradle.plugins:license-gradle-plugin:0.11.0"
    classpath "org.ajoberstar:gradle-git:1.7.2"
  }
}


configurations.all {
    resolutionStrategy {
        force 'xml-apis:xml-apis:1.4.01'
    }
}
// task wrapper(type: Wrapper) {
//   gradleVersion = "2.11"
// }

allprojects {
  repositories {
    mavenLocal()
    mavenCentral()
    maven {
      url "https://repository.mulesoft.org/nexus/content/repositories/public"
    }
  }
}


apply plugin: "license"
apply plugin: "idea"
apply plugin: "java"
apply plugin: "project-report"

license {
  header rootProject.file('license_header.txt')
  exclude "src/test/resources/svnserver"
}

dependencies {
  //compile fileTree(dir:'libs',include:['*.jar'])
  implementation "org.jetbrains:annotations:16.0.3"
  implementation "org.eclipse.jgit:org.eclipse.jgit:5.7.0.202003110725-r"
  implementation "org.tmatesoft.svnkit:svnkit:1.10.1"
  implementation "org.yaml:snakeyaml:1.26"
  implementation "org.ini4j:ini4j:0.5.4"
  implementation "com.beust:jcommander:1.72"
  implementation "commons-io:commons-io:2.6"
  implementation "org.atteo.classindex:classindex:3.6"
  implementation "org.mapdb:mapdb:3.0.7"
  implementation "com.unboundid:unboundid-ldapsdk:4.0.7"
  /// use jackson decode json
  implementation group: 'com.fasterxml.jackson.core', name: 'jackson-core', version: '2.10.2'
  implementation group: 'com.fasterxml.jackson.core', name: 'jackson-databind', version: '2.10.2'
  implementation group: 'com.fasterxml.jackson.core', name: 'jackson-annotations', version: '2.10.2'
  //implementation "com.google.code.gson:gson:2.8.5"
  implementation "org.apache.httpcomponents:httpclient:4.5.11"
  implementation "net.consensys.cava:cava-toml:0.5.0"
  implementation "org.apache.logging.log4j:log4j-core:2.16.0"
  implementation "org.apache.logging.log4j:log4j-slf4j-impl:2.16.0"
  implementation "org.redisson:redisson:3.12.5"

  testImplementation "org.apache.directory.server:apacheds-protocol-ldap:2.0.0-M19"
  testImplementation "org.apache.directory.api:api-ldap-codec-standalone:1.0.0-M26"
  testImplementation "org.testng:testng:6.8.8"
  testImplementation("org.testcontainers:testcontainers:1.5.0")

}

sourceCompatibility = JavaVersion.VERSION_1_8
targetCompatibility = JavaVersion.VERSION_1_8

idea {
  project {
    jdkName = sourceCompatibility.name
    languageLevel = sourceCompatibility.name
  }
  module {
    jdkName = sourceCompatibility.name
    downloadJavadoc = true
    downloadSources = true
  }
}

tasks.withType(JavaCompile) {
  options.compilerArgs << "-Xlint:unchecked" << "-Xlint:deprecation"
  options.encoding = "UTF-8"
}

test {
  useTestNG()
  maxHeapSize = "384m"
  ignoreFailures = "$testIgnoreFailures".toBoolean()
}

jar {
  manifest {
    attributes(
        "Main-Class": "svnserver.server.Main",
        "Class-Path": "${-> createLauncherClassPath()}"
    )
  }
}

processResources {
  expand([
      "revision": org.ajoberstar.grgit.Grgit.open(project.file(rootProject.projectDir)).head().id,
      "tag"     : (System.getenv("TRAVIS_TAG") ?: ""),
  ])
}

task deployJars(dependsOn: jar) {
  doLast {
    def projectArtifacts = configurations.archives.artifacts*.file
    def fullArtifacts = configurations.archives.artifacts*.file + configurations.runtimeClasspath.files
    copy {
      from fullArtifacts.intersect(projectArtifacts)
      from "README.md"
      from "launcher"
      from "launcher.profile.bash"
      from "launcher.vmoptions"
      from "sserver.toml"
      from "svn.toml"
      from "log4j.xml"
      from "log4j.debug.xml"
      from "LICENSE"
      into "${project.buildDir}/deploy"
      }
      copy {
        from fullArtifacts.minus(projectArtifacts)
        into "${project.buildDir}/deploy/vendors"
        }
  }
}

task deployZip(type: Zip, dependsOn: deployJars) {
  from "build/deploy"
}

def createLauncherClassPath() {
  def projectArtifacts = configurations.archives.artifacts*.file
  def fullArtifacts = configurations.archives.artifacts*.file + configurations.runtimeClasspath.files
  def vendorJars = fullArtifacts.minus(projectArtifacts).collect { "vendors/${it.name}" }
  return vendorJars.join(" ")
}