apply plugin: 'jetty'
apply plugin: 'java'
apply plugin: 'groovy'
apply plugin: 'war'
apply plugin: 'idea'

version = '1.0'
sourceCompatibility = 1.8
targetCompatibility = 1.8

repositories {
    mavenLocal()
    maven { url = "https://repo1.maven.org/maven2" }
    maven { url 'https://oss.jfrog.org/libs-snapshot' }
    maven { url = "http://maven.oschina.net/content/groups/public/" }
}

ext {
    avajeebeanorm_agent_version = '4.7.1'
    jettyVersion = "9.3.7.v20160115"
}

// ============================================
// enhance ebean's model
configurations {
    ebeanagent
}

dependencies {
    ebeanagent "org.avaje.ebeanorm:avaje-ebeanorm-agent:${avajeebeanorm_agent_version}"
}

task enhanceEbean {
    doLast {
        ant.taskdef(name: 'ebean', classname: 'com.avaje.ebean.enhance.ant.AntEnhanceTask', classpath: project.configurations.ebeanagent.asPath)
        ant.ebean(classSource: project.sourceSets.main.output.classesDir,
                packages: 'emailserving.domain.**', transformArgs: 'debug=1')
    }
}

project.compileJava << {
    enhanceEbean.execute()
}

project.compileTestJava << {
    enhanceEbean.execute()
}

// enhance ebean's model
// ============================================


jettyRun {
    contextPath = '/'
    reload = "automatic"
    httpPort = 7979
    scanIntervalSeconds = 1
}



//Project dependencies
dependencies {
    //include in compile only, exclude in the war
    compile(
            'org.springframework:spring-webmvc:4.2.4.RELEASE',
            'commons-fileupload:commons-fileupload:1.3.1',
            'javax.mail:mail:1.4.7',
            'org.apache.velocity:velocity:1.7',
            'com.fasterxml.jackson.core:jackson-core:2.7.0'
    )

    //utils
    compile(
            'commons-io:commons-io:2.4',
            'joda-time:joda-time:2.9.2',
            'com.google.guava:guava:19.0')

    //log
    compile(
            "org.slf4j:slf4j-api:1.7.12",
            "ch.qos.logback:logback-classic:1.1.3",
            "ch.qos.logback:logback-core:1.1.3")

    // persist
    compile('org.avaje.ebeanorm:avaje-ebeanorm:6.16.1') {
        exclude group: 'com.fasterxml.jackson.core', module: 'jackson-core' // its duplicate for jetty
    }
    compile 'org.apache.commons:commons-dbcp2:2.1.1'
    compile 'mysql:mysql-connector-java:5.1.38'


    // test
    testCompile('org.subethamail:subethasmtp:3.1.7')
    testCompile('org.springframework:spring-test:4.2.4.RELEASE')
    testCompile('org.codehaus.groovy:groovy-all:2.3.2')
    testCompile('com.h2database:h2:1.4.191')
    testCompile('org.avaje.ebeanorm:avaje-ebeanorm:6.16.1')
    testCompile group: 'junit', name: 'junit', version: '4.11'

    compile('org.springframework:spring-context-support:4.2.4.RELEASE') {
        exclude group: 'javax.servlet.jsp-api'
        exclude group: 'javax.servlet.jsp'
        exclude group: 'javax.servlet.jsp-api'
    }

    compile "org.eclipse.jetty:jetty-server:$jettyVersion"
    compile "org.eclipse.jetty:jetty-webapp:$jettyVersion"
    compile "org.eclipse.jetty:jetty-servlet:$jettyVersion"


    providedCompile('javax.servlet:javax.servlet-api:3.1.0')
}


war {
    // unzip and add all jetty dependencies into the root of our war file
    from {
//        configurations.embeddedJetty.collect {
//            project.zipTree(it)
//        }
        configurations.compile.collect {
            project.zipTree(it)
        }
    }
    // remove signature and unnecessary files
    exclude "META-INF/*.SF", "META-INF/*.RSA", "about.html", "about_files/**", "readme.txt", "plugin.properties", "jetty-dir.css"

    // include only the classes which will be used to start Embedded Jetty
    from "$buildDir/classes/main"

    // tells the class to run when the generate war be executed using 'java -jar'
    manifest { attributes 'Main-Class': 'emailserving.EmbeddedJetty' }
}